Question:
we can get into the document flow screen when we are in SO windows.
but how to get into it when I'm in my program.
i don't know to to call the screen.
could u tell me?
Answer:
read document flow table VBFA.
_________________
Cheers,
syd
Answer:
I just want to get into the doc flow screen directly, so that i won't want to output the flow data mannually.
Answer:
FM CALL_TRANSACTION_FROM_TABLE
with
I_TCODE = VA03
I_MODE = E
I_UPDATE = A
Table
T_BDCDATA with
Prog. Screen Start fnam fval
SAPMV45A 0102 X
BDC_CURSOR VBAK-VBELN
BDC_OKCODE =IFLU
VBAK-VBELN <Your SO>
(Slightly jacked up, But I'am sure you could understand)
KRK
Answer:
Here is how I have done it in the past........
FORM DOCUMENT_FLOW USING VBELN
POSNR.
DATA: VBCO6 LIKE VBCO6.
CLEAR VBCO6.
IF POSNR IS INITIAL.
* Header
SELECT SINGLE * FROM VBAK
WHERE VBELN = VBELN.
MOVE-CORRESPONDING VBAK TO VBCO6.
CALL DIALOG 'RV_DOCUMENT_FLOW'
EXPORTING
VBCO6 FROM VBCO6
* MAKT-MAKTX FROM SPACE
* KNA1-KUNNR FROM KUAGV-KUNNR
* KNA1-NAME1 FROM KUAGV-NAME1
* MAKT-MATNR FROM SPACE
IVKORG FROM VBAK-VKORG
IVTWEG FROM VBAK-VTWEG.
ELSE.
* Line Item.
SELECT SINGLE * FROM VBAK
WHERE VBELN = VBELN.
SELECT SINGLE * FROM VBAP
WHERE VBELN = VBELN
AND POSNR = POSNR.
MOVE-CORRESPONDING VBAP TO VBCO6.
CALL DIALOG 'RV_DOCUMENT_FLOW'
EXPORTING
VBCO6 FROM VBCO6
MAKT-MAKTX FROM VBAP-ARKTX
* KNA1-KUNNR FROM KUAGV-KUNNR
* KNA1-NAME1 FROM KUAGV-NAME1
MAKT-MATNR FROM VBAP-MATNR
IVKORG FROM VBAK-VKORG
IVTWEG FROM VBAK-VTWEG.
ENDIF.
ENDFORM.
Regards,
R Heilman
Answer:
I'll try it immediately with ur help.
Answer:
under heilman's guide, i finished the work.
but with the clue from kumar, i write down the procedure:
FORM DOCUMENT_FLOW USING VBELN POSNR.
DATA: TBDCDATA LIKE BDCDATA OCCURS 1 WITH HEADER LINE.
TBDCDATA-PROGRAM = 'SAPMV45A'.
TBDCDATA-DYNPRO = '0102'.
TBDCDATA-DYNBEGIN = 'X'.
TBDCDATA-FNAM = VBELN.
TBDCDATA-FVAL = 'IFLU'.
CALL FUNCTION 'CALL_TRANSACTION_FROM_TABLE'
EXPORTING
I_TCODE = 'VA03'
I_MODE = 'A'
I_UPDATE = 'A'
TABLES
T_BDCDATA = TBDCDATA
* T_BDCMESSAGES =
* T_PARAMETER_IDS =
EXCEPTIONS
ERROR_FOUND = 1
OTHERS = 2
.
IF SY-SUBRC <> 0.
*MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
ENDFORM.
but in running, it stays in screen 0102, not the flow screen.
where is my coding fault?
Answer:
Finished?? I suggest you read up on BDC.
Anyway......
R H's CALL DIALOG example is the easiest way to tackle your problem.
PARAMETERS: vbeln LIKE vbak-vbeln.
SELECT SINGLE * FROM vbak
WHERE vbeln = vbeln.
MOVE-CORRESPONDING vbak TO vbco6.
CALL DIALOG 'RV_DOCUMENT_FLOW'
EXPORTING
vbco6 FROM vbco6
ivkorg FROM vbak-vkorg
ivtweg FROM vbak-vtweg.
If you want to go down the BDC path your code will have to look something like this.
PARAMETERS: vbeln LIKE vbak-vbeln.
DATA: tbdcdata LIKE bdcdata OCCURS 1 WITH HEADER LINE.
tbdcdata-program = 'SAPMV45A'.
tbdcdata-dynpro = '0102'.
tbdcdata-dynbegin = 'X'.
APPEND tbdcdata.
CLEAR tbdcdata.
tbdcdata-fnam = 'VBAK-VBELN'.
tbdcdata-fval = vbeln.
APPEND tbdcdata.
CLEAR tbdcdata.
tbdcdata-fnam = 'BDC_OKCODE'.
tbdcdata-fval = 'IFLU'.
APPEND tbdcdata.
CLEAR tbdcdata.
CALL FUNCTION 'CALL_TRANSACTION_FROM_TABLE'
EXPORTING
i_tcode = 'VA03'
i_mode = 'E'
i_update = 'A'
TABLES
t_bdcdata = tbdcdata
EXCEPTIONS
error_found = 1
OTHERS = 2.
IF sy-subrc <> 0.
ENDIF.
_________________
Its ABAPER spelt backwards.........
Answer:
thank u, repaba.
I resolved the problem occured in my coding.
best regards to u all.